PROCEDURE dum$display_initiated_job_list, display_initiated_job_list, disijl (
  display_option, do: key
    (job_name, jn)
    (brief, b)
    (full, f, all)
  keyend = brief
  output, o: file = $output
  status)

 " This procedure displays a brief summary of all jobs in the
 " initiated job list.   This procedure uses RJTs new dump analyzer
 " and assumed TMM$DISPATCHER has been added.

   set_file_attributes output fc=legible pf=continuous
  current = $default_module
  chadm tmm$dispatcher
  job_display = ' '
  job_name_string = ''
  FOR block = 0 TO $pv(jmv$ijl_p.max_block_in_use) DO
     FOR entry = 0 TO $pv(UPPERVALUE(0.jmt$ijl_block_index)) DO
       IF $pv(jmv$ijl_p.block_p^[?block].index_p^[?entry].entry_status) <>  JMC$IES_ENTRY_FREE THEN
         IF display_option = job_name THEN
           job_name_string = job_name_string//'    '//..
$pv(jmv$ijl_p.block_p^[?block].index_p^[?entry].job_name)
            IF $size(job_name_string) >= 70 THEN
              disv job_name_string o=output.$eoi
             job_name_string = ''
           IFEND
         ELSEIF display_option = brief THEN
         job_display = '- '//$strrep(block)//' '//$strrep(entry)//' '//..
$pv(jmv$ijl_p.block_p^[?block].index_p^[?entry].system_supplied_name)//' '//..
$pv(jmv$ijl_p.block_p^[?block].index_p^[?entry].job_name)//' '//..
$pv(jmv$ijl_p.block_p^[?block].index_p^[?entry].entry_status)
   "     dispv jmv$ijl_p.block_p^[?block].index_p^[?entry]
         disv job_display o=output.$eoi
         job_display = '  ajl '//..
$strrep($pv(jmv$ijl_p.block_p^[?block].index_p^[?entry].ajl_ordinal),16)//'(16)'// ..
'  kjl '//$strrep($pv(jmv$ijl_p.block_p^[?block].index_p^[?entry].kjl_ordinal),16)//'(16)'//..
'  '//..
$pv(jmv$ijl_p.block_p^[?block].index_p^[?entry].swap_status)//'  job_fixed_asid: '//..
$strrep($pv(jmv$ijl_p.block_p^[?block].index_p^[?entry].job_fixed_asid),16)//'(16)'
         disv job_display o=output.$eoi
       ELSEIF display_option = full then
         disv ' --- Block '//$strrep(block)//' --Entry '//$strrep(entry) o=output.$eoi
         dispv jmv$ijl_p.block_p^[?block].index_p^[?entry] o=output.$eoi
       IFEND
       IFEND
     FOREND
  FOREND
   IF $size(job_name_string) > 0 THEN
      disv job_name_string o=output.$eoi
   IFEND


  chadm $name(current)
 PROCEND dum$display_initiated_job_list
