PROCEDURE dum$display_mat_change_request, display_mat_change_request, dismcr (
  address, a, pva: integer = 1400006088(16)
  output, o: file = $output
  status)

"THIS PROCEDURE DISPLAYS DMT$MAT_CHANGE_REQUEST AND ITS ASSOCIATED
" DMT$MAT_CHANGES

  crev s status
  detf $local.djh_mat_change_requests status=s
  setfa $local.djh_mat_change_requests fc=legible pf=continuous pw=80
  out_file = '$local.djh_mat_change_requests'

  putl '                     MAT CHANGE REQUESTS' o=$fname(out_file//'.$eoi')

  dism $value(address) b=11 o=$fname(out_file//'.$eoi')

  request_addr = $value(address)
  code = $mem(request_addr, 1, m)
  avti = $mem(request_addr+1, 2, m)
  numb = $mem(request_addr+3, 2, m)
  changes_addr = $mem(request_addr+5, 6, m)
  putl ' ' o=$fname(out_file//'.$eoi')
  putl ' code = '//$strrep(code)//', avt index = '//$strrep(avti)//', number of changes = '//$strrep(numb) ..
        o=$fname(out_file//'.$eoi')
  putl ' ' o=$fname(out_file//'.$eoi')

  dism changes_addr b=(numb*4) e=m o=$fname(out_file//'.$eoi')
  putl ' ' o=$fname(out_file//'.$eoi')

  FOR index = 1 TO numb DO
    addr = changes_addr + ((index - 1)* 4)
    style = $mem(addr, 1, m)
    dau = $mem(addr+1, 3, m)
    putl ' '//$strrep(index)//'.  style = A'//$strrep(style)//', dau address = '//$strrep(dau) ..
          o=$fname(out_file//'.$eoi')
  FOREND

  copf $fname(out_file) $value(output)

  detf $local.djh_mat_change_requests status=s

PROCEND dum$display_mat_change_request
