PROCEDURE dum$display_served_families, display_served_families, dissf (
  output, o : file = $output
  status: (VAR, BY_NAME) status = $optional
  )

  " This proc displays the served family table.
  " This proc requires RJTs most recent dump analyzer.
  " The proc assumes that dfm$mtr_served_family_manager has been added.

  current_module = $default_module
  chadm dfm$mtr_served_family_manager
  crev local_status status
  IF $file(output open_position) = '$BOI' THEN
    rewind_file output status=local_status
  IFEND
  set_file_attributes output fc=legible pf=continuous
  out = output.$eoi

  IF $program_value(dfv$served_family_table_root.valid) THEN
    FOR pnter = 1 TO $pv(..
          dfv$served_family_table_root.number_of_active_pointers) DO
      FOR family = 1 TO $program_value(dfv$served_family_table_root..
.p_family_list_pointer_array^[?pnter].highest_valid_entry) DO
        disv 'Family '//$strrep(family)//' ------- ' o=out
        dispv dfv$served_family_table_root.p_family_list_pointer_array^[?..
pnter].p_served_family_list^[?family] o=out
      FOREND
    FOREND
  ELSE
    disv ' No served families' o=out
  IFEND
  chadm current_module

PROCEND dum$display_served_families
