
PROC dum$display_swap_transitions, display_swap_transitions, disst (output, o: file = $output)

  crev stat status
  crev id (string 30) d=0..26
  id(00) = '     NULL                    '
  id(01) = ' R - EXECUTING               '
  id(02) = 'TI - IDLE_TASKS_INITIATED    '
  id(03) = 'TJ - JOB_IDLE_TASKS_COMPLETE '
  id(04) = 'S0 - SWAPPED_NO_IO           '
  id(05) = 'FA - FLUSH_AM_PAGES          '
  id(06) = 'AJ - JOB_ALLOCATE_SWAP_FILE  '
  id(07) = 'AW - WAIT_ALLOCATE_SWAP_FILE '
  id(08) = 'AF - ALLOCATE_SWAP_FILE      '
  id(09) = 'JW - WAIT_JOB_IO_COMPLETE    '
  id(10) = 'JC - JOB_IO_COMPLETE         '
  id(11) = 'DW - WAIT_ALLOCATE_SFD       '
  id(12) = 'AD - ALLOCATE_SFD            '
  id(13) = 'SD - SWAPPED_IO_CANNOT_INIT  '
  id(14) = 'OS - INITIATE_SWAPOUT_IO     '
  id(15) = 'OW - WAIT_SWAPOUT_IO_INIT    '
  id(16) = 'OI - SWAPOUT_IO_INITIATED    '
  id(17) = 'OC - SWAPOUT_IO_COMPLETE     '
  id(18) = 'S2 - SWAPPED_IO_COMPLETE     '
  id(19) = 'FM - FREE_SWAPPED_MEMORY     '
  id(20) = ' S - SWAPOUT_COMPLETE        '
  id(21) = 'IR - SWAPIN_REQUESTED        '
  id(22) = 'IS - SWAPIN_RESOURCE_CLAIMED '
  id(23) = 'IW - WAIT_SWAPIN_IO_INIT     '
  id(24) = 'II - SWAPIN_IO_INITIATED     '
  id(25) = 'IC - SWAPIN_IO_COMPLETE      '
  crev in integer d=0..30 v=0
  crev out integer d=0..30 v=0
  oo = $string($value(output)) // '.$eoi'
  b = $sa(jsv$swap_state_statistics)
  FOR f = 0 TO 25 DO
    FOR t = 0 TO 25 DO
      c = $mem(b+f*26*16+t*16+12 4)
      IF c > 0 THEN
        in(t) = in(t)+c
        out(f) = out(f)+c
        putl ' '//id(f)//'--> '//id(t)//'  '//$strrep(c) o=$fname(oo)
      IFEND
    FOREND
  FOREND
  putl ' ' o=$fname(oo)
  putl ' ' o=$fname(oo)
  FOR i = 0 TO 25 DO
    if (in(i)>0) OR (out(i)>0) then
      ic = '          '//$strrep(in(i))
      ic = $substr(ic $strlen(ic)-7 8)
      oc = '          '//$strrep(out(i))
      oc = $substr(oc $strlen(oc)-7 8)
      if in(i)=out(i) then
        dif = '.'
      else
        dif = ', difference = '//$strrep(in(i)-out(i))
      ifend
      putl ' '//id(i)//', in= '//ic//',   out = '//oc//dif o=$fname(oo)
    ifend
  FOREND

PROCEND dum$display_swap_transitions
