PROCEDURE dum$display_update_fmd_length, display_update_fmd_length (
  address, a: integer = $required
  output, o: file = $output
  address_mode, am: key
      pva, sva
    keyend = sva
  status)

  "$FORMAT=OFF"
  VAR
    indent: string 5 = '     '
    log_address: integer = address
    output_file: file
    output_line: string = ' '
  VAREND
  "$FORMAT=ON"

  IF $file(output open_position) = '$BOI' THEN
    output_file = output.$asis
  ELSE
    output_file = output
  IFEND

  log_address = log_address + 1

  display_binary_unique_name log_address o=output_file cs=indent//'gfn = ' am=address_mode
  output_line = indent//'dfl = '//$strrep($mem(log_address+11, 3, job, 0, address_mode), 16)//'(16)'

  IF $mem(log_address+14, 1, job, 0, address_mode) <> 0 THEN
    output_line = output_line//', fmd_length = '//..
$strrep($mem(log_address+15, 6, job, 0, address_mode), 16)//'(16)'
  IFEND

  IF $mem(log_address+21, 1, job, 0, address_mode) <> 0 THEN
    output_line = output_line//', logical_length = '//..
$strrep($mem(log_address+22, 6, job, 0, address_mode), 16)//'(16)'
  IFEND

  putl output_line o=output_file

PROCEND dum$display_update_fmd_length
