*copyc OSD$DEFAULT_PRAGMATS
?? NEWTITLE := 'NOS/VE : Interactive Facility' ??
?? NEWTITLE := '  [XDCL] iip$report_unhandled_super_msg' ??
MODULE iim$report_unhandled_super_msg;


{ Global External Procedure Declarations
*copyc IFV$MODULE_FOR_C180
?? SET (LIST := OFF) ??
*copyc PMP$LOG
?? SET (LIST := ON) ??


{ Global Constants and Types
?? SET (LIST := OFF) ??
*copyc OST$STATUS
*copyc iit$application_names_messages
?? SET (LIST := ON) ??

?? TITLE := 'PROCEDURE [XDCL] iip$report_unhandled_super_msg', EJECT ??

  PROCEDURE [XDCL] iip$report_unhandled_super_msg (VAR msg:
    iit$input_supervisory_message);

    CONST
      legend_1 = 'Unhandled input supervisory message:',
      legend_2 = 'ABT:  ; ADR:     ; ACT:   ; IBU:      ; TLC:     ',
      legend_3 = 'TYPE:      ';

    VAR
      line: string (60),
      status: ost$status,
      i: integer;

{ Log the kind of error report that is to follow

    pmp$log (legend_1, status);

{ Log the block type, address, character type, block undeliverable,
{   and text length

    line (1, 49) := legend_2;
    STRINGREP (line (5, 2), i, msg.header.block_type);
    STRINGREP (line (13, 5), i, msg.header.address);
    STRINGREP (line (24, 3), i, msg.header.character_type);
    STRINGREP (line (33, 6), i, msg.header.undeliverable);
    STRINGREP (line (45, 5), i, msg.header.text_length);
    pmp$log (line (1, 49), status);

{ Log the message block type

    line (1, 11) := legend_3;
    STRINGREP (line (6, 6), i, msg.message_type);
    pmp$log (line (1, 11), status);

  PROCEND iip$report_unhandled_super_msg;
MODEND
