*copyc osd$default_pragmats
MODULE iim$st_get_input_output_counts;
?? NEWTITLE := 'Module iim$st_get_input_output_counts' ??
?? NEWTITLE := 'Global Declarations' ??
?? PUSH (LISTEXT := ON) ??
*copyc iit$connection_description
*copyc iip$st_clr_input_output_counts
*copyc iiv$connection_desc_ptr
*copyc osc$timesharing_terminal_file
*copyc osd$integer_limits
*copyc ost$status
?? POP ??

?? TITLE := '[XDCL] iip$st_get_input_output_counts', EJECT ??

  PROCEDURE [XDCL, #GATE] iip$st_get_input_output_counts
    (VAR input_count: ost$non_negative_integers;
     VAR output_count: ost$non_negative_integers;
     VAR status: ost$status);

    VAR
      connection_desc_ptr: ^iit$connection_description;

    status.normal := true;
    input_count := 0;
    output_count := 0;

    IF iiv$connection_desc_ptr = NIL THEN
      RETURN;
    ELSE
      connection_desc_ptr := iiv$connection_desc_ptr;
      WHILE connection_desc_ptr <> NIL DO
        IF connection_desc_ptr^.session_layer_file_name =
          osc$timesharing_terminal_file THEN
          input_count := input_count + connection_desc_ptr^.job_input_count;
          output_count := output_count + connection_desc_ptr^.job_output_count;
        IFEND;
        connection_desc_ptr := connection_desc_ptr^.next_connection_desc_ptr;
      WHILEND;

      iip$st_clr_input_output_counts (status);
    IFEND;

  PROCEND iip$st_get_input_output_counts;

MODEND iim$st_get_input_output_counts;








