*BEGIN  IODMAC5
 OVERLAY  SPACE  4,10
**        OVERLAY - DEFINE OVERLAY TITLE AND LOAD ADDRESS
*
*         THIS MACRO MUST BE THE FIRST LINE OF THE OVERLAY.
*         IT GENEERATES THE IDENT, TITLE, AND ORG PSEUDO
*         INSTRUCTIONS.  TAG OVLA MUST BE EQUATED TO A DEFAULT
*         LOAD ADDRESS IF THE SECOND VARIABLE ON THE OVERLAY
*         MACRO IS LEFT BLANK.

          PURGMAC OVERLAY
 ALPHABET MICRO  1,25,*ABCDEFGHIJKLMNOP*
 OVERLAY  MACRO  DESC,LOADADD
          LOCAL  AD
          QUAL
          NOREF  OVLN
 OVLL     SET    OVLL+1
          IFEQ   OVLL,21,2
          SET    1
 OVLU     SET    OVLU+1
 OVLN     SET    OVLU*20+OVLL-21
 CHL      MICRO  OVLL,1,*"ALPHABET"*
 CHU      MICRO  OVLU,1,*"ALPHABET"*
 NU       OCTMIC OVLN,2
 AD       OCTMIC LOADADD OVLA
          TITLE  "PRGNAM""CHU""CHL" ("NU") - DESC
          BASE   O
          IDENT  "PRGNAM""CHU""CHL","AD" "NU" DESC
          ORG    "AD"
          BASE   *
          ENDM
 OVLL     SET    1           INITIALIZE OVERLAY NUMBER
 OVLU     SET    1
 ROUTINE  SPACE  4,10
**        ROUTINE - DEFINE AN OVERLAY NAME AND NUMBER
*
*         THIS MACRO MUST BE USED WITHIN AN OVERLAY TO DEFINE
*         ITS NAME AND OVERLAY NUMBER.  BOTH OF THESE SYMBOLS
*         ARE REQUIRED BY THE LOADOVL MACRO.

          PURGMAC ROUTINE
 ROUTINE  MACRO  NAME
 NAME     BSS    0
 NAME_O   EQU    OVLN
          ENDM
 LOADOVL  SPACE  4,10
**        LOADOVL - LOAD AN OVERLAY
*
*         THIS MACRO LOADS AN OVERLAY WHOSE NAME WAS DEFINED BY A
*         ROUTINE MACRO.  THIS MACRO REQUIRES 4 CONSECUTIVE DIRECT
*         CELLS.  THE FIRST ONE MUST HAVE A TAG NAME OF T1.  ALSO,
*         THREE CONSECUTIVE LOCATIONS BEGINNING WITH TAG DH MUST
*         CONTAIN THE REFORMATTED RMA OF THE OVERLAY DIRECTORY.
*           DH - BITS 21-31 OF THE DIRECTORY RMA RIGHT JUSTIFIED
*           DH+1 - BITS 9-20 OF THE DIRECTORY RMA RIGHT JUSTIFIED
*           DH+2 - BITS 3-8 OF THE DIRECTORY RMA RIGHT JUSTIFIED

          PURGMAC LOADOVL
 LOADOVL  MACRO  NAME
          LDN    NAME_O
          RJM    LNO         LOAD NEXT OVERLAY
          ENDM
*END IODMAC5
