?? RIGHT := 110 ??
?? NEWTITLE := 'NOS/VE Job Management : Get Encrypted Password' ??
MODULE jmm$get_encrypted_password;

{ PURPOSE:
{   This module contains the routine to retrieve a users encrypted password.
{
{ DESIGN:
{   This module will access the user's validation file and retrieve the user's
{ encrypted password.  This module resides in a 236 library.

?? NEWTITLE := 'Global Declarations Referenced By This Module' ??
?? PUSH (LISTEXT := ON) ??
*copyc ost$name
*copyc ost$status
?? POP ??
*copyc avp$prevalidate_job
*copyc pmp$get_user_identification
?? OLDTITLE ??
?? NEWTITLE := '[XDCL, #GATE] jmp$get_encrypted_password', EJECT ??
*copy jmh$get_encrypted_password

  PROCEDURE [XDCL, #GATE] jmp$get_encrypted_password
    (VAR encrypted_password: ost$name;
     VAR status: ost$status);

    VAR
      user_identification: ost$user_identification,
      validation_default: array [1 .. 1] of avt$validation_item;

    status.normal := TRUE;
    pmp$get_user_identification (user_identification, status);
    IF NOT status.normal THEN
      RETURN;
    IFEND;

    validation_default [1].key := avc$password_key;
    avp$prevalidate_job (user_identification.user, user_identification.family,
          { validation_attributes } NIL, ^validation_default, status);
    IF status.normal THEN
      encrypted_password := validation_default [1].password;
    IFEND;

  PROCEND jmp$get_encrypted_password;
?? OLDTITLE ??
MODEND jmm$get_encrypted_password;
