?? TITLE := 'NOS/VE :  NETWORK ACCESS METHOD' ??
MODULE nam$se_send_data;
?? RIGHT := 110 ??

{ MODULE DECK NAM$SE_SEND_DATA }

?? NEWTITLE := 'Global Declarations Referenced By This Module', EJECT ??
?? PUSH (LISTEXT := ON) ??
*copyc amc$condition_code_limits
*copyc ame$improper_file_id
*copyc amt$fap_declarations
*copyc ost$caller_identifier
?? POP ??
*copyc baf$task_file_entry_p
*copyc osp$set_status_abnormal
?? OLDTITLE ??
?? NEWTITLE := '[#gate, xdcl] NAP$SE_SEND_DATA', EJECT ??
*copyc amh$also
*copyc nah$se_send_data

  PROCEDURE [#GATE, XDCL] nap$se_send_data
    (    file_identifier: amt$file_identifier;
         data: nat$data_fragments;
         end_of_message: boolean;
         qualified_data: boolean;
         wait: ost$wait;
     VAR activity_status: ost$activity_status;
     VAR status: ost$status);

    CONST
      interface_name = 'NAP$SE_SEND_DATA',
      fap_layer_number = 0;

    VAR
      call_block: amt$call_block,
      file_instance_p: ^bat$task_file_entry;

    status.normal := TRUE;
    file_instance_p := baf$task_file_entry_p (file_identifier);
    IF file_instance_p = NIL THEN
      osp$set_status_abnormal (amc$access_method_id, ame$improper_file_id,
            interface_name, status);
      RETURN; {----->
    IFEND;

    call_block.operation := nac$se_send_data_req;

    call_block.se_send_data_req.data := ^data;
    call_block.se_send_data_req.end_of_message := end_of_message;
    call_block.se_send_data_req.qualified_data := qualified_data;
    call_block.se_send_data_req.wait := wait;
    call_block.se_send_data_req.activity_status := ^activity_status;

    file_instance_p^.fap_control_information.first_fap.access_method^
          (file_identifier, call_block, fap_layer_number, status);

    IF NOT status.normal THEN
      IF (file_instance_p^.instance_attributes.dynamic_label.error_exit_procedure <> NIL) THEN
        file_instance_p^.instance_attributes.dynamic_label.error_exit_procedure^ (file_identifier, status);
      IFEND;
    IFEND;

  PROCEND nap$se_send_data;
?? OLDTITLE ??
MODEND nam$se_send_data;
