  PROCEDURE [INLINE] osp$test_set_main_sig_lock
    (VAR lock: ost$signature_lock;
     VAR locked: boolean);

?? PUSH (LISTEXT := ON) ??
*copyc clc$compiling_for_test_harness
*copyc fsc$compiling_for_test_harness

    ?IF NOT (clc$compiling_for_test_harness OR fsc$compiling_for_test_harness)
          THEN

      VAR
        new_value: integer,
        actual_value: integer,
        cs_status: 0 .. 2,
        task_id: ost$global_task_id,
        xcb_p: ^ost$execution_control_block;

      xcb_p := #ADDRESS (1, osc$segnum_job_fixed_heap,
            #READ_REGISTER (osc$pr_base_constant));
      task_id := xcb_p^.global_task_id;
      new_value := task_id.index * 256 * #SIZE (task_id.seqno) + task_id.seqno;
      locked := TRUE;
      xcb_p^.system_table_lock_count := xcb_p^.system_table_lock_count + 256;
      REPEAT
        #COMPARE_SWAP (lock.lock_id, 0, new_value, actual_value, cs_status);
      UNTIL cs_status <> osc$cs_variable_locked;

      IF cs_status = osc$cs_successful THEN
        RETURN;
      IFEND;
      xcb_p^.system_table_lock_count := xcb_p^.system_table_lock_count - 256;
      IF (xcb_p^.system_table_lock_count <= 0) AND xcb_p^.system_give_up_cpu THEN
        syp$cycle_for_lock (tmc$cyc_tstset_sys_lock, ^lock);
      IFEND;
      locked := FALSE;
      IF new_value = actual_value THEN
        osp$system_error ('Lock already set by current task', NIL);
      IFEND;
    ?ELSE
      locked := lock.lock_id <> 0;
    ?IFEND

  PROCEND osp$test_set_main_sig_lock;
*copyc ost$execution_control_block
*copyc syp$cycle_for_lock
*copyc osc$processor_defined_registers
*copyc ost$heap
*copyc ost$signature_lock
*copyc osp$system_error
?? POP ??
