PROCEDURE display_all_files, disaf (
  recorded_vsn, rvsn: list of any of
      key
        all
      keyend
      name 1..6
    anyend = all
  output_disposition, odi: any of
      key
        (discard_all_output, dao),(discard_standard_output, dso),
        (printer, p),(wait_queue, wt, wq)
      keyend
      file
    anyend = puv$display_all_files, printer
  status)

  IF $specified(recorded_vsn) THEN
    include_volumes_command = 'include_volumes recorded_vsns=' // $string($parameter_value(recorded_vsn), source)
  ELSE
    include_volumes_command = 'include_volumes recorded_vsns=all'
  IFEND

  JOB job_name=display_all_files job_class=system substitution_mark='?' output_disposition=output_disposition
    " display all files on the specified volumes
    SYSTEM_OPERATOR_UTILITY capability=system_administration
      TASK ring=3
        BACKUP_PERMANENT_FILES backup_file=$null
          set_list_options cycle_display_options=(recorded_vsn modification_date_time access_date_time size)..
                 display_excluded_items=false
          set_backup_options exclude_catalog_information=true include_exception_conditions=none
          ?include_volumes_command?
          backup_all_files
        QUIT
      TASKEND
    QUIT
  JOBEND

PROCEND display_all_files
