
PROC makqcu_phase_1, makqcu1  (
qcu_ident, qcu: name = $required
delivery_medium, dm: boolean
continue : VAR of boolean
no_pause, np : boolean)

"******************************************************************************
" This phase will produce a catalog containing all the modified OS
" libraries and generate the QCU correction package.
"
" At completion, the new CP will be in $user.qcu_FC (Field changes)
"******************************************************************************

$value(continue) = TRUE
crev count
crev work k=string
crev ignore k=status
crev msg k=string
crev qi   k=string v=$string($value(qcu_ident))
crev wev$working_catalog k=string scope=xref
crev wev$build_level k=string scope=xref
crev qev$psr k=string scope=xref
p1 = $substr(qi,5,2)
work_path = wev$working_catalog
build = wev$build_level


"******************************************************************************
" This section will search the PACS catalog and locate the path
" descriptor for each library generated. The purpose of this is to aid
" in determining what materials make up the QCU.
"******************************************************************************
crev temp1_path k=string v=$unique//'.$asis'

"*****************************************************************************
" Define base level, current level and previous correction catalog paths
" for use by the define correction subproduct.
"*****************************************************************************
crev blc_path k=string v='.'//$job(user)//'.'//$strrep(qi)//'_PA'
     blc_path = blc_path//'.NOSVE_MAINTENANCE'

crev clc_path k=string v='.'//$job(user)//'.'//$strrep(qi)//'_PB'
     clc_path = clc_path//'.NOSVE_MAINTENANCE'

crev pcc_path k=string v='.'//$job(user)//'.'//$strrep(qi)//'_PB'

crev fcc_path k=string v='.'//$job(user)//'.'//$strrep(qi)//'_FC'

crev first k=boolean v=true
crev r k=integer d=1..3
crev local_status  k=status
crev cnt v=0
crev mypath k=string v=''
crev idnt k=string v=''
crev found k=boolean
crev type
crev element k=string

delcc $fname(fcc_path) status=ignore
delc  $fname(fcc_path) status=ignore




putl ' '
putl ' Building  new staging data for '
putl ''
putl '        PSR   '//$string(qev$psr)
putl ' '
putl '             And now ...'
putl ''

PACS

putl '   "Would you tell me, please, which way I ought to go from here."'
 CRESC   status=local_status
        EXIT_PROC with local_status WHEN NOT local_status.normal

putl '   "That depends a great deal on where you want to get to," said the cat.'


  DEFC n=NOSVE_MAINTENANCE blc=$fname(blc_path) clc=$fname(clc_path) status=local_status
        EXIT_PROC with local_status WHEN NOT local_status.normal
putl '   "I don''t much care where --," said Alice.'
putl '   "Then it doesn''t matter which way you go," ...'

   CHACA  pa=$name(qev$psr)
        EXIT_PROC with local_status WHEN NOT local_status.normal


putl '   "-- So long as I get somewhere," ...'
putl '   "Oh, you''re sure to do that," said the cat,'
   GENC pc=$fname(fcc_path)  status=local_status
        EXIT_PROC with local_status WHEN NOT local_status.normal


 QUIT
QUIT
        EXIT_PROC with local_status WHEN NOT local_status.normal

putl '    "If you only walk long enough."'



"***********************************************************************
" The correction package is complete
"***********************************************************************

IF $value(continue) THEN
   makqcu2,$value(qcu_ident),$value(delivery_medium),$value(no_pause)
IFEND

 PROCEND makqcu_phase_1
