PROC activate_ftps (
  load_map, lm : file = $optional
  status       : var of status = $optional
  )


*IF $variable(rav$proc_doc,declared)<>'UNKNOWN'

"   This request activates FTPS.
*IFEND


  create_variable ignore_status k=status
  create_variable local_status k=status
  create_variable ftp_library k=string v='$system.tcp_ip.ftp_bound_product'


  IF NOT $file($fname(ftp_library) permanent) THEN
    put_line ('  ', ' --ERROR-- Unable to activate:  FTP is not installed.') o=$response
    EXIT_PROC
  IFEND

  IF $specified(load_map) THEN
    map_file = $string($value(load_map))
    options = 'all'
  ELSE
    map_file = '$null'
    options = 'none'
  IFEND

  remove_system_task name=ftp_server status=local_status
  IF NOT local_status.normal AND ($condition(local_status.condition) <> 'OSE$SYSTEM_TASK_NOT_DEFINED') THEN
    EXIT_PROC WITH local_status
  IFEND

  define_system_task name=ftp_server library=$fname(ftp_library) ..
        starting_procedure=ipp$ftp_server_initialization automatic_restart=false restart_after_idle=true ..
        deactivate_task_option=terminate idle_task_option=terminate load_map=$fname(map_file) ..
        load_map_options=$name(options) termination_error_level=error status=local_status

  EXIT_PROC WITH local_status WHEN NOT local_status.normal

  activate_system_task task_name=ftp_server status=local_status

  EXIT_PROC WITH local_status

PROCEND activate_ftps

