PROCEDURE activate_mail_cluster_server (
  job_class, jc: name = $job_default(job_class, batch)
  status)

  "$FORMAT=OFF"
  VAR
    application_job_name: name = $name('MAIL_DFS_SRVR'//$mainframe(id))
    ignore_status: status
    dfs_library: file = $system.applications.distributed_file_server.ver_1_0.dfs$site_command_library
    dfs_job_log: file = $system.mailve_v2.dfs_job_log
    manna_status: status
    select_status: status
    submit_status: status
    system_job_name: name
  VAREND
  "$FORMAT=ON"

  IF (NOT $file(dfs_library permanent)) THEN
    put_line lines=('  ', ..
          ' --ERROR-- Unable to activate:  Distributed File Server is not i..
nstalled.') o=$response
    EXIT_PROC
  IFEND

  MANAGE_JOBS
    select_job login_user=$system login_family=$system ..
          name=application_job_name job_state=(deferred, queued, initiated) ..
          status=select_status
    IF select_status.normal THEN
      IF $size(jmv$selected_jobs) > 0 THEN
        put_line ' MAILVE_CLUSTER_SERVER is already active as ..
              job:'           o=$response
        display_value jmv$selected_jobs o=$response
        EXIT PROCEDURE
      IFEND
    ELSE
      EXIT procedure WITH select_status
    IFEND
  QUIT

  JOB user_job_name=application_job_name job_class=job_class ..
        job_recovery_disposition=terminate job_abort_disposition=terminate ..
        output_disposition=dfs_job_log substitution_mark='?' ..
        system_job_name=system_job_name job_execution_ring=4 ..
        status=submit_status

    SYSTEM_OPERATOR_UTILITY capability=system_administration
      create_command_list_entry ?dfs_library?
      start_remote_access_server
    QUIT

  JOBEND

  IF submit_status.normal THEN
    put_line ' MAILVE_CLUSTER_SERVER has been activated as job  '//..
$string(application_job_name)//' ('//$string(system_job_name)//').' ..
          o=$response
  ELSE
    put_line ' --ERROR-- Unable to submit job for MAILVE_CLUSTER_SERVER.' ..
          o=$response
  IFEND
  EXIT procedure WITH submit_status WHEN NOT submit_status.normal

PROCEND activate_mail_cluster_server
