PROCEDURE deactivate_inetd (
  status)

*IF $variable(rav$proc_doc,declared)<>'UNKNOWN'

" Purpose:  Deactivate the Internet Daemon.
*IFEND

  VAR
    application_job_name: name = $name('INTERNET_DMN'//$mainframe(id))
    select_status: status
    terminate_status: status
  VAREND

  MANAGE_JOBS
    SELECT_JOB ..
      name=application_job_name job_state=all status=select_status
    IF select_status.normal THEN
      IF $size(jmv$selected_jobs) > 0 THEN
        WHILE $size(jmv$selected_jobs) > 0 DO
          terminate_job job_name=$first(jmv$selected_jobs) ..
            status=terminate_status
          IF terminate_status.normal THEN
            put_line ' Internet Daemon '//$string($first(jmv$selected_jobs))//..
' terminated.' o=$response
          ELSE
            display_value $status_message(terminate_status, 80) o=$response
          IFEND
          jmv$selected_jobs =$rest(jmv$selected_jobs)
        WHILEND
      ELSE
        put_line ' The Internet Daemon is not active.' o=$response
      IFEND
    ELSE
      EXIT procedure WITH select_status
    IFEND
  QUIT

PROCEND deactivate_inetd
