PROCEDURE deactivate_mail_delivery_agent, deamda (
  message_transfer_agent, mta: (BY_NAME, ADVANCED) any of
      string 1..12
      name 1..12
    anyend = mvd$default_mta, ' '
  status)


"   This request terminates the MAILVE Custom Delivery job.

  VAR
    active_mta: string = $string(message_transfer_agent)
  VAREND

  IF $size($trim(active_mta)) = 0 THEN
    active_mta = 'MAILVE'
  IFEND

  VAR
    application_job_name: name = $name('MVE_CD_'//active_mta//$mainframe(id))
    select_status: status
    terminate_status: status
  VAREND

  MANAGE_JOBS
    SELECT_JOB login_user=$SYSTEM login_family=$SYSTEM ..
      name=application_job_name job_state=all status=select_status
    IF select_status.normal THEN
      IF $size(jmv$selected_jobs) > 0 THEN
        WHILE $size(jmv$selected_jobs) > 0 DO
          terminate_job job_name=$first(jmv$selected_jobs) ..
            status=terminate_status
          IF terminate_status.normal THEN
            put_line ' MAILVE Custom Delivery '//$string($first(jmv$selected_jobs))//..
' terminated.' o=$response
          ELSE
            display_value $status_message(terminate_status, 80) o=$response
          IFEND
          jmv$selected_jobs=$rest(jmv$selected_jobs)
        WHILEND
      ELSE
        put_line ' MAILVE Custom Delivery Job is not active.' o=$response
      IFEND
    ELSE
      EXIT procedure WITH select_status
    IFEND
  QUIT

PROCEND deactivate_mail_delivery_agent

