PROC rap$define_btfs (
  family_names, family_name, fn: list of name 1..26 = $required
  status)


*IF $variable(wev$proc_doc,declared)<>'UNKNOWN'

"   This request defines BTFS.
*IFEND


    create_variable command_file k=string v='$local.'//$unique
    create_variable ignore_status k=status
    create_variable local_status k=status


  collect_text $fname(command_file) until='  collect_end' sm='?'
    $system.osf$command_library.manage_network_applications
      define_server server=osa$batch_transfer_server protocol=cdna_session nam_initiated=false
        change_connection_priority cp=2
        change_accept_connection ac=false
        change_maximum_connections mc=40
        change_server_validation sp=false
        add_client_address si=cdcnet ai=all
        FOR i = 1 TO $set_count(family_names) DO
          include_line 'add_titles btfs$'//$string($value(family_name i))
        FOREND
      end_define_server
      activate_server server=osa$batch_transfer_server
    quit
  collect_end

  include_file $fname(command_file) status=local_status
  detach_file $fname(command_file) status=ignore_status

  IF local_status.normal THEN
    put_line ' BTFS application is defined' o=$response
  IFEND

  EXIT_PROC WITH local_status

PROCEND rap$define_btfs
