PROC rap$define_ptf (
  family_names, family_name, fn: list of name 1..26 = $required
  status)


*IF $variable(wev$proc_doc,declared)<>'UNKNOWN'

"    This request defines the PTF and PTFS applications.
"
"    The prefix 'PTFS$' is required on all family names and is
"automatically added so that the user does'nt have to add it.
*IFEND


    create_variable command_file k=string v='$local.'//$unique
    create_variable ignore_status k=status
    create_variable local_status k=status
    create_variable title k=(string $max_name)


  collect_text $fname(command_file) until='  collect_end'
    $system.osf$command_library.manage_network_applications
      define_client client=osa$file_transfer_client protocol=cdna_session
        change_connection_priority cp=4
        change_maximum_connections mc=40
        change_client_validation sp=true
        change_application_identifier ai=2001
      end_define_client
      activate_client client=osa$file_transfer_client

      define_server server=osa$file_transfer_server protocol=cdna_session ..
           nam_initiated=false
        change_connection_priority cp=4
        change_maximum_connections mc=40
        change_server_validation sp=true
        change_accept_connection ac=false
        add_client_address si=nosve ai=2001
        add_client_address si=cdcnet ai=all

        FOR i =  1 TO $set_count(family_names) DO
          include_line 'add_titles ptfs$'//$string($value(family_name, i))
        FOREND

      end_define_server
      activate_server server=osa$file_transfer_server
    quit
  collect_end

  include_file $fname(command_file) status=local_status
  detach_file $fname(command_file) status=ignore_status

  IF local_status.normal THEN
    put_line ' PTF application is defined' o=$response
  IFEND

  EXIT_PROC WITH local_status

PROCEND rap$define_ptf

