PROC define_ptf_for_rhfam (
  client_maximum_connections, cmc : integer 1..255 = 10
  server_maximum_connections, smc : integer 1..255 = 10
  status                          : var of status = $optional
  )

  create_variable define_ptf_status kind=status
  create_variable ignore_status kind=status

  create_variable cr_requested kind=string

  create_variable rhfam_utility_installed kind=boolean value=false
  create_variable rhfam_microcode_installed kind=boolean value=false

  create_variable command_file k=string v='$local.'//$unique
  create_variable rhfam_utility_file k=string v='$system.rhfam.osf$rhfam_network_utilities'
  create_variable rhfam_microcode k=string v='$system.rhfam.microcode.c180'

  rhfam_utility_installed = $file($fname(rhfam_utility_file), permanent)
  rhfam_microcode_installed = $file($fname(rhfam_microcode), permanent)
  IF (NOT rhfam_utility_installed) OR (NOT rhfam_microcode_installed) THEN
    put_line ('  ', ' --ERROR-- Product RHFAM is not installed.') o=$response
    accept_line cr_requested input p='Press NEXT:'
    EXIT_PROC
  IFEND

COLLECT_TEXT $fname(command_file) until='END_MANAGE_RHFAM_NETWORK'
  MANAGE_RHFAM_NETWORK
    define_rhfam_client client=ptf maximum_connections=$value(client_maximum_connections)
    activate_rhfam_client client=ptf
    define_rhfam_server server=ptfs rhfam_initiated=FALSE ..
      maximum_connections=$value(server_maximum_connections) accept_connection=FALSE ..
      rhfam_validates_connection_lid=TRUE
    activate_rhfam_server server=ptfs
    quit
END_MANAGE_RHFAM_NETWORK

  include_file $fname(command_file) status=define_ptf_status
  detach_file $fname(command_file) status=ignore_status
  EXIT_PROC WITH define_ptf_status WHEN NOT define_ptf_status.normal

  put_line ' PTF/PTFS defined for RHFAM' o=$response

PROCEND define_ptf_for_rhfam

