PROC rap$define_qtfs (
  family_names, family_name, ..
  fn                         : list of name 1..26 = $required
  status                     : var of status = $optional
  )


*IF $variable(rav$proc_doc,declared)<>'UNKNOWN'

"   This request defines and activates the NAM/VE QTF server application.
"   This definition is retained across deadstarts.
*IFEND


  create_variable command_file kind=string value='$local.'//$unique
  create_variable ignore_status kind=status
  create_variable local_status kind=status
  create_variable title kind=(string $max_name)


COLLECT_TEXT $fname(command_file) until='COLLECT_END'
    $system.osf$command_library.manage_network_applications
      define_server server=osa$queue_transfer_server protocol=cdna_session ..
           nam_initiated=false
        change_connection_priority connection_priority=4
        change_maximum_connections maximum_connections=40
        change_server_validation system_privilege=true
        change_accept_connection accept_connection=false
        add_client_address system_identifier=nosve application_identifier=2006
        add_client_address system_identifier=cdcnet application_identifier=all

        FOR i =  1 TO $set_count(family_names) DO
          include_line statement_list='add_titles qtfs$'//$string($value(family_name, i))//' broadcast_registration=true'
        FOREND

      end_define_server
      activate_server server=osa$queue_transfer_server
    quit
COLLECT_END

  include_file file=$fname(command_file) status=local_status
  delete_file file=$fname(command_file) status=ignore_status

  EXIT_PROC WITH local_status WHEN NOT local_status.normal

  put_line line=' QTF server application defined for NAM/VE' output=$response

PROCEND rap$define_qtfs
