PROC define_qtfs_for_rhfam (
  maximum_connections, mc : integer 1..255 = 10
  status                  : var of status = $optional
  )


*IF $variable(rav$proc_doc,declared)<>'UNKNOWN'

"   This request defines and activates the RHFAM/VE QTF server application.
"   This definitions is NOT retained across deadstarts.
*IFEND


  create_variable command_file kind=string value='$local.'//$unique
  create_variable cr_requested kind=string
  create_variable define_qtfs_status kind=status
  create_variable ignore_status kind=status
  create_variable rhfam_utility_installed kind=boolean value=false
  create_variable rhfam_microcode kind=string value='$system.rhfam.microcode.c180'
  create_variable rhfam_microcode_installed kind=boolean value=false
  create_variable rhfam_utility_file kind=string ..
        value='$system.rhfam.osf$rhfam_network_utilities'

  rhfam_utility_installed = $file($fname(rhfam_utility_file), permanent)
  rhfam_microcode_installed = $file($fname(rhfam_microcode), permanent)
  IF (NOT rhfam_utility_installed) OR (NOT rhfam_microcode_installed) THEN
    put_line lines=('  ', ' --ERROR-- Product RHFAM/VE is not installed.') o=$response
    accept_line variable=cr_requested input=input prompt='Press NEXT:'
    EXIT_PROC
  IFEND

COLLECT_TEXT output=$fname(command_file) until='COLLECT_END'
  MANAGE_RHFAM_NETWORK
    define_rhfam_server server=qtfs rhfam_initiated=FALSE ..
      maximum_connections=$value(maximum_connections) accept_connection=FALSE ..
      rhfam_validates_connection_lid=FALSE
    activate_rhfam_server server=qtfs
    quit
COLLECT_END

  include_file file=$fname(command_file) status=define_qtfs_status
  delete_file file=$fname(command_file) status=ignore_status
  EXIT_PROC WITH define_qtfs_status WHEN NOT define_qtfs_status.normal

  put_line line=' QTF server application defined for RHFAM/VE' output=$response

PROCEND define_qtfs_for_rhfam
