PROC define_qtf_for_rhfam (
  maximum_connections, mc : integer 1..255 = 10
  status                  : var of status = $optional
  )


*IF $variable(rav$proc_doc,declared)<>'UNKNOWN'

"   This request defines and activates the RHFAM/VE QTF client application.
"   This definition is NOT retained across deadstarts.
*IFEND


  create_variable command_file kind=string value='$local.'//$unique
  create_variable cr_requested kind=string
  create_variable define_qtf_status kind=status
  create_variable ignore_status kind=status
  create_variable rhfam_microcode kind=string value='$system.rhfam.microcode.c180'
  create_variable rhfam_microcode_installed kind=boolean value=false
  create_variable rhfam_utility_installed kind=boolean value=false
  create_variable rhfam_utility_file kind=string ..
        value='$system.rhfam.osf$rhfam_network_utilities'

  rhfam_utility_installed = $file($fname(rhfam_utility_file), permanent)
  rhfam_microcode_installed = $file($fname(rhfam_microcode), permanent)
  IF (NOT rhfam_utility_installed) OR (NOT rhfam_microcode_installed) THEN
    put_line lines=('  ', ' --ERROR-- Product RHFAM/VE is not installed.') output=$response
    accept_line variable=cr_requested input=input prompt='Press NEXT:'
    EXIT_PROC
  IFEND

COLLECT_TEXT $fname(command_file) until='COLLECT_END'
  MANAGE_RHFAM_NETWORK
    define_rhfam_client client=qtf maximum_connections=$value(maximum_connections)
    activate_rhfam_client client=qtf
    quit
COLLECT_END

  include_file file=$fname(command_file) status=define_qtf_status
  delete_file file=$fname(command_file) status=ignore_status
  EXIT_PROC WITH define_qtf_status WHEN NOT define_qtf_status.normal

  put_line line=' QTF client application defined for RHFAM/VE' output=$response

PROCEND define_qtf_for_rhfam
