PROC rap$delete_opes (
  terminate_active_connections, tac : boolean = false
  status                            : var of status = $optional
  )


*IF $variable(wev$proc_doc,declared)<>'UNKNOWN'

"   This request deletes OPES.
*IFEND


  create_variable command_file k=string v='$local.'//$unique
  create_variable delete_status k=status
  create_variable ignore_status k=status
  create_variable local_status k=status


COLLECT_TEXT $fname(command_file) until='COLLECT_END'
  $system.osf$command_library.manage_network_applications
    deactivate_client client=osa$station_operator tac=$value(terminate_active_connections) ..
          status=delete_status
    IF delete_status.normal OR ($condition(delete_status.condition) = 'NAE$APPLICATION_ALREADY_INACTIV') THEN
      delete_client client=osa$station_operator status=delete_status
    IFEND

    IF delete_status.normal OR ($condition(delete_status.condition) = 'NAE$UNKNOWN_APPLICATION') THEN
      delete_status.normal = true
    IFEND
  quit
COLLECT_END

  include_file $fname(command_file) status=local_status
  detach_file $fname(command_file) status=ignore_status

  EXIT_PROC WITH local_status WHEN NOT local_status.normal
  EXIT_PROC WITH delete_status WHEN NOT delete_status.normal

PROCEND rap$delete_opes
