PROCEDURE delete_ptf_for_rhfam (
  status)


*IF $variable(rav$proc_doc,declared)<>'UNKNOWN'

"   This request deactivates and deletes the RHFAM/VE PTF client and
"   server applications.
*IFEND


  VAR
    command_file: file=$unique($local)
    delete_ptf_status: status
    delete_ptfs_status: status
    ignore_status: status
    local_status: status
  VAREND

COLLECT_TEXT output=command_file until='COLLECT_END'
  MANAGE_RHFAM_NETWORK
    deactivate_rhfam_client client=ptf status=delete_ptf_status
    IF delete_ptf_status.normal OR ($condition(delete_ptf_status.condition) = ..
          'RFE$APPL_ALREADY_INACTIVE') THEN
      delete_rhfam_client client=ptf status=delete_ptf_status
    IFEND
  quit
COLLECT_END

  include_file file=command_file status=local_status
  delete_file file=command_file status=ignore_status
  EXIT_PROC WITH local_status WHEN NOT local_status.normal
  EXIT_PROC WITH delete_ptf_status WHEN NOT delete_ptf_status.normal

  put_line line=' PTF client application deleted for RHFAM/VE' output=$response

COLLECT_TEXT output=command_file until='COLLECT_END'
  MANAGE_RHFAM_NETWORK
    deactivate_rhfam_server server=ptfs status=delete_ptfs_status
    IF delete_ptfs_status.normal OR ($condition(delete_ptfs_status.condition) ..
          = 'RFE$APPL_ALREADY_INACTIVE') THEN
      delete_rhfam_server server=ptfs status=delete_ptfs_status
    IFEND
  quit
COLLECT_END

  include_file file=command_file status=local_status
  delete_file file=command_file status=ignore_status
  EXIT_PROC WITH local_status WHEN NOT local_status.normal
  EXIT_PROC WITH delete_ptfs_status WHEN NOT delete_ptfs_status.normal

  put_line line=' PTF server application deleted for RHFAM/VE' output=$response

PROCEND delete_ptf_for_rhfam
