PROC rap$delete_scfs (
  application_name, an              : name = $optional
  terminate_active_connections, tac : boolean = false
  status                            : var of status = $optional
  )


*IF $variable(rav$proc_doc,declared)<>'UNKNOWN'

"   This request deletes SCFS.
*IFEND


  create_variable command_file k=string v='$local.'//$unique
  create_variable delete_status k=status
  create_variable ignore_status k=status
  create_variable local_status k=status


  application_name = 'osa$status_control_fac_server'

  IF $specified(application_name) THEN
    application_name = $string($value(application_name))
  IFEND

COLLECT_TEXT $fname(command_file) until='COLLECT_END' sm='?'
  $system.osf$command_library.manage_network_applications

    deactivate_server server=?application_name? tac=$value(terminate_active_connections) ..
          status=delete_status
    IF delete_status.normal OR ($condition(delete_status.condition) = 'NAE$APPLICATION_ALREADY_INACTIV') THEN
      delete_server server=?application_name? status=delete_status
    IFEND
    IF delete_status.normal OR ($condition(delete_status.condition) = 'NAE$UNKNOWN_APPLICATION') THEN
      delete_status.normal = true
    IFEND

  quit
COLLECT_END

  include_file $fname(command_file) status=local_status
  detach_file $fname(command_file) status=ignore_status

  EXIT_PROC WITH local_status WHEN NOT local_status.normal
  EXIT_PROC WITH delete_status WHEN NOT delete_status.normal


PROCEND rap$delete_scfs
