PROCEDURE rap$delete_tftp (
  terminate_active_connections, tac: boolean = false
  status)

*IF $variable(rav$proc_doc,declared)<>'UNKNOWN'

"    This request deletes the TFTP client.
"
*IFEND

  VAR
    command_file: file = $unique($local)
    delete_status: status
    ignore_status: status
    local_status: status
  VAREND

COLLECT_TEXT command_file until='COLLECT_END'
  $system.osf$command_library.MANAGE_NETWORK_APPLICATIONS
    deactivate_client client=osa$tftp_client tac=terminate_active_connections ..
          status=delete_status
    IF delete_status.normal OR ($condition(delete_status.condition) = 'NAE$APPLICATION_ALREADY_INACTIV') THEN
      delete_client client=osa$tftp_client status=ignore_status
    IFEND

    deactivate_tcpip_application application=osa$tftp_client tas=terminate_active_connections ..
          status=delete_status
    IF delete_status.normal OR ($condition(delete_status.condition) = 'NAE$APPLICATION_ALREADY_INACTIV') THEN
      delete_tcpip_application application=osa$tftp_client status=ignore_status
    IFEND
  QUIT
COLLECT_END

  include_file command_file status=local_status
  delete_file command_file status=ignore_status

PROCEND rap$delete_tftp
