
" This is DEVELOPMENT'S VERSION of the SYSTEM_INITIATION_EPILOG file.
" It is stored in the catalog
" $SYSTEM.PROLOGS_AND_EPILOGS.  The commands in this file are executed every
" time the system is initiated.
"
" Execution of this file occurs inside a procedure with a WHEN handler so
" that every command in this file will be attempted, regardless of errors.
" In addition you have the status variables IGNORE_STATUS and LOCAL_STATUS
" available to you.

    create_variable osv$deadstart_phase kind=(string $max_name) s=xref
    create_variable rav$development_deadstart kind=boolean s=xref
    create_variable st_string kind=string

  IF rav$development_deadstart THEN
    change_job_attribute_defaults login_family=NVE

"   Terminate the HPA periodic job.

    job jn=terj_hpa odi=dso
      VAR
        ign_stat: status
      VAREND
      terminate_job jn=HPA_VE$MONITOR_JOB odi=dso status=ign_stat
      terminate_job jn=HPA_VE$PERIODIC_JOB odi=dso status=ign_stat
    jobend
    IF (osv$deadstart_phase = 'INSTALL') THEN

"     Create file_transfer job and service classes and activate the profile.

      administer_scheduling
        administer_service_class
          create_class class_name=file_transfer default_values=batch
          change_attribute class_name=file_transfer maximum_active_jobs=40
        quit
        administer_job_class
          create_class class_name=file_transfer default_values=batch
          change_attribute class_name=file_transfer ..
                immediate_initiation_candidate=true
          change_attribute class_name=file_transfer initiation_level=40
          change_attribute class_name=file_transfer ..
                initial_service_class=file_transfer
        quit
      quit save_change=true
      manage_active_scheduling
        activate_profile profile=$system.scheduling_profile ..
              enable_job_reclassification=true
      quit save_change=true

      IF (NOT $file($user.testing_user_prolog, assigned)) THEN
        COLLECT_TEXT o=$user.testing_user_prolog until='        **END_OF_PROLOG**'
         create_command_list_entry e=($system.osf$site_command_library, $system.scu.command_library) p=after
         IF $file($user.prolog, assigned) THEN
           include_file f=$user.prolog
         IFEND
        **END_OF_PROLOG**
        detach_file f=$user.testing_user_prolog status=ignore_status
        create_file_permit f=$system.testing_user_prolog g=public am=all sm=none
        change_file_attributes f=$system.testing_user_prolog ra=(3 13 13)
      IFEND
      st_string = $SUBSTR($PROCESSOR(MODEL_NUMBER),1,3)
      FOR I = 1 TO (3-$STRLEN($PROCESSOR(SERIAL,0))) DO
        st_string = st_string//'0'
      FOREND
      st_string = st_string//$processor(serial,0)
      validate_development_users family=nve family_user_administrator=eval ..
        password=evalx dv=true
      validate_development_users family=$name('v'//st_string) family_user_administrator=eval ..
        password=evalx dv=false
      validate_development_users family=$name('testve'//st_string) family_user_administrator=eval ..
        password=evalpw dv=false
      validate_development_users family=testing family_user_administrator=eval  ..
        password=evalpw dv=false
    IFEND
    create_command_list_entry e=$system.osf$site_command_library
  IFEND
