PROC display_hpa_summary, dishs (
  input, i: file = $local.$engineering_log
  output, o: file = $output
  status)

"          PROC display_hpa_summary displays a summary of the errors reported
"            in the system Engineering_Log (binary).  This summary is an
"            edited version of the output produced by the utility DISBL.
"
"            parameters are as follows:
"              input or i   = name of a file containing an engineering log.
"              output or o = name of file to recieve the output
"
  create_variable (input_line, output_line) k=string
  create_variable local_status k=status
  create_variable in_file k=string v=$unique
  create_variable test k=string "variable to hold parameter evaluation"

"           create line for display_binary_log call here"

  IF $job(mode) = 'INTERACTIVE' THEN
    out_file = '$local.'//$unique
    put_line 'display_binary_log i='//$string($value(input))//' o='//out_file ..
          o=$fname(in_file//'.$boi')
  ELSE
    put_line 'disbl i='//$string($value(input))//' o='//$string($value(output))..
           o=$fname(in_file//'.$boi')
  IFEND

COLLECT_TEXT $fname(in_file//'.$eoi')
  defg all_errors
  disdd all_errors
  QUIT
**

  include_file $fname(in_file)

  IF $job(mode) = 'INTERACTIVE' THEN

"         build output file name for line by line output"

    output_attached_by_proc = FALSE
    setfa $value(output) fc=list
    put_line '' o=$value(output)
    out_name = $path($value(output), catalog) // '.' // ..
          $path($value(output), last) // '.'
    IF $file($value(output), permanent) THEN
      out_name = out_name // $strrep($file($value(output), cycle_number)) // ..
            '.$asis'
      IF NOT $file($value(output), attached) THEN
        attach_file $value(output) am=all sm=none
        output_attached_by_proc = TRUE
      IFEND
    ELSE
      out_name = out_name // '$asis'
    IFEND

    lines_read = 0
    accept_line input_line $fname(out_file//'.$boi') line_count=lines_read
    WHILE lines_read > 0 DO
      output_line = $substr(input_line, 1, 71)
      IF output_line = '0 ***  There is no elements for this group' THEN
        output_line = ..
              '0 ***  SELECTED LOG CONTAINS NO ERROR STATISTICS OF THIS TYPE'
      IFEND

      put_line output_line $fname(out_name) status=local_status
      accept_line input_line $fname(out_file//'.$asis') line_count=lines_read
    WHILEND
    detach_file $fname(out_file) status=local_status
  IFEND

  detach_file $fname(in_file) status=local_status
  IF output_attached_by_proc THEN
    detach_file $value(output)
  IFEND

PROCEND display_hpa_summary
