?? RIGHT := 110 ??
?? NEWTITLE := 'RAP$DISPLAY_PSRS_ANSWEREDS procedure.' ??
MODULE ram$display_psrs_answered;

{ PURPOSE:
{   This module contains the procedures to display an array of psrs.
{
{ DESIGN:
{   The compiled module resides in RAF$LIBRARY.
{
{ NOTES:
{

?? NEWTITLE := 'Global Declarations Referenced by This Module', EJECT ??
?? PUSH (LISTEXT := ON) ??
*copyc rac$max_line
*copyc clt$display_control
*copyc ost$status
*copyc rat$subproduct_info_types
?? POP ??
*copyc rap$write_strings

?? TITLE := '[XDCL] rap$display_psrs_answered', EJECT ??

{ PURPOSE:
{   This procedure displays the PSRs that are answered by a
{   correction.
{
{ DESIGN:
{   The procedure loops through an array of PSRs displaying each
{   psr.
{
{ NOTES:
{
{

  PROCEDURE [XDCL] rap$display_psrs_answered
    (    psrs_answered_p: ^rat$psrs_answered;
     VAR display_control: clt$display_control;
     VAR status: ost$status);


    VAR
      display_status: ost$status,
      indent: 0 .. rac$max_line,
      i: rat$psrs_answered_count;

    status.normal := TRUE;
    display_status.normal := TRUE;
    indent := 19;

    IF psrs_answered_p <> NIL THEN

      rap$write_strings ('    Answers PSRs: (', '', TRUE, 0, display_control, display_status);

      FOR i := 1 TO UPPERBOUND (psrs_answered_p^) DO

        IF i = 1 THEN
          rap$write_strings ('', psrs_answered_p^ [i], TRUE, indent, display_control,
                display_status);
        ELSE
          rap$write_strings (' ', psrs_answered_p^ [i], TRUE, indent, display_control,
                display_status);
        IFEND;

      FOREND;

      rap$write_strings (')', '', FALSE, 0, display_control, display_status);

    IFEND;

    IF status.normal AND (NOT display_status.normal) THEN
      status := display_status;
    IFEND;

  PROCEND rap$display_psrs_answered;

  MODEND ram$display_psrs_answered;
