.PROC,EDICAT*I,
N "- Name of CATALOG entry point"      = (*N=GENCAT,*F)
.
.HELP
 The EDICAT procedure EDIts the entry point name of the CATALOG
 binaries to make it different than the standard NOS entry point.

 Parameter   Default   Description
   Name       Value

  [n]        gencat    entry point name for CATALOG binary

.HELP,N
 The N parameter names the entry point to be used for the CATALOG
 binaries. The default value is GENCAT. You must change the GENCAT
 name in the DISLIB procedure if you change this entry point.

.ENDHELP
$NOTE,OUTPUT,NR.+ CHANGING CATALOG ENTRY POINT TO N
GETLIB,CATALOG,T=ABS,G=TAPE1.
$CATALOG,TAPE1,R.
FTN5,I,L=0,GO.
$RENAME,N=TAPE1.
$CATALOG,N,R.
$UNLOAD,LGO,COMPILE.
REPLIB,N.
$SKIP,NOERROR.
  $EXIT.
  $UNLOAD,CATALOG.
  $REVERT,ABORT. ENTRY POINT NOT CHANGED
$ENDIF,NOERROR.
$REVERT. N --> NVELIB
.DATA,COMPILE
      PROGRAM BINEDT
      INTEGER RECRD(3000),ORD,RECLEN
      BUFFER IN (1,1) (RECRD(1),RECRD(3000))
      ORD=O"20"+1
      RECRD(ORD)=L"N".OR.(RECRD(ORD).AND.O"777777")
      IF (UNIT(1))3,5,5
3     CONTINUE
      REWIND 1
      RECLEN=LENGTH(1)
      BUFFER OUT(1,1) (RECRD(1),RECRD(RECLEN))
5     CONTINUE
      STOP
      END
/EOR
