.PROC,GENJT*I,
VSN "Volume Serial Number of DS tape"  = (*N=,
                                     *S6(ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789)),
D "tape Density (GE,PE,HD,HY)"         = (*N=PE,GE,PE,HD,HY),
PT "Production Template file name"     = (*N=PROJT,*F)
.
.HELP
 The GENJT procedure GENerates NOS/VE Job Template file
 from the deadstart file created by the GENNVE procedure.
 Requires the DSMDSTG binaries.

 Parameter   Default   Description
   Name       Value

  [vsn]                 deadstart tape volume serial number
  [d]           pe      deadstart tape density (ge,pe,hd,hy)
  [pt]         projt    production job template file name

.HELP,VSN
 The VSN parameter specifies the deadstart tape volume serial number.
 The default is to attach a permanent file named TPXXXK.
.HELP,D
 The D parameter specifies the deadstart tape density.
 The default density is PE.
.HELP,PT
 The PT parameter names the permanent file to which the Production
 NOS/VE Job Template is written. The default value is PROJT.
.ENDHELP
GETNVE(TPXXXK,TPXXXK,,,VSN,D)
$GTR(TPXXXK,JT)PJBTMPL
$NOTE(INFILE)/RESTORE,PT,PJBTMPL/END
DSMDSTG(INFILE,JT,LIST)
REPFILE,PT,PT,DEFINE=YES.
$UNLOAD(JT,PT,LIST,INFILE,TPXXXK)
$SKIP,NOERROR.
  $EXIT.
  $UNLOAD,LIST,TPXXXK,INFILE,JT,PT.
  $IFE,(EF.EQ.TIE).OR.(EF.EQ.TAE),TERMINATED.
    $EXIT. GENJT *TERMINATED*
  $ENDIF,TERMINATED.
  $REVERT,ABORT. TEMPLATE GENERATION ERROR
$ENDIF,NOERROR.
$REVERT. TEMPLATE --> PT
/EOR
