PROCEDURE (osm$getmrf) get_multi_record_file, getmrf (
  nos_ve_file, nvf: file = $required
  nos_file, nf: name 7 = $required
  status)

  "$FORMAT=OFF
  VAR
    lsts: status
  VAREND
  "$FORMAT=ON"
  detach_file $local.nos_tape_ic_file status=lsts
  detach_file $local.nos_xfer status=lsts

  IF $job(c170_os_type) = 'NOS' THEN
    "$FORMAT=OFF
    VAR
      sv: array 1 .. 13 of string
    VAREND
    "$FORMAT=ON"
    sv(1) = 'jobc.'
    sv(2) = 'common(system)'
    sv(3) = 'gtr(system,nvelib,u)ulib/nvelib'
    sv(4) = 'library(nvelib/a)'
    sv(5) = 'settl,*.'
    sv(6) = 'setasl,*.'
    sv(7) = 'setjsl,*.'
    sv(8) = 'return,tape.'
    sv(9) = 'getfile(tape,' // $string(nos_file) // ',,read,yes)'
    sv(10) = 'xpfua.'
    sv(11) = 'exit.'
    sv(12) = 'dayfile,day.'
    sv(13) = 'replace,day.'

  ELSE
    "$FORMAT=OFF
    VAR
      sv: array 1 .. 8 of string
    VAREND
    "$FORMAT=ON"
    catalog_id = $nosbe_catalog_id
    sv(1) = 'JOBC,T0.'
    sv(2) = 'LIBRARY(NVELIB)'
    sv(3) = 'GETFILE(TAPE,' // $string(nos_file) // ',' // catalog_id // ',READ,YES)'
    sv(4) = 'XPFUA.'
    sv(5) = 'EXIT.'
    sv(6) = 'REQUEST(DAY,PF)'
    sv(7) = 'DAYFILE,DAY.'
    sv(8) = 'CATALOG(DAY,ID=' // catalog_id // ')'
  IFEND

  set_file_attributes $local.nos_tape_ic_file ui='sv'
  request_link $local.nos_tape_ic_file
  set_file_attributes $local.nos_xfer fap=rap$nos_file_read
  execute_task sp=rap$getmrf l=$system.osf$system_library p=$string(nos_ve_file) lmo=none
  detach_file ($local.nos_tape_ic_file, $local.nos_xfer) status=lsts

PROCEND get_multi_record_file
