.PROC,INSDF*I,
VSN "Volume Serial Number of DS tape"  = (*N=,
                                     *S6(ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789)),
D "tape Density (GE,PE,HD,HY)"         = (*N=PE,GE,PE,HD,HY),
B "Base user" =(*N,*F),
.
.HELP
 The INSDF procedure INStalls a shortened version of the NOS/VE
 Deadstart File for Continuation and Recovery deadstarts.

 Parameter   Default   Description
   Name       Value

  [vsn]                 deadstart tape volume serial number
  [d]           pe      deadstart tape density (ge,pe,hd,hy)
  [b]                   base user

.HELP,VSN
 The VSN parameter specifies the deadstart tape volume serial number.
 The default is to attach a permanent file named TPXXXK.
.HELP,D
 The D parameter specifies the deadstart tape density.
 The default density is PE.
.HELP,B
  The B parameter specifies the base user number used to obtain the
  deadstart tape if not found on the default user number.
  The default is no base user.
.ENDHELP
GETNVE(TPXXXK,TPXXXK,,B,VSN,D)
DSMDSTG(NVEDIR,,LIST)
REWIND(TPXXXK,NVETAPE)
COPYBR,TPXXXK,NEWTAPE.    * DEADSTART PP
GTR,TPXXXK,NEWTAPE.MARK00-DCFILE
SKIPEI,NEWTAPE.
COPY,NVETAPE,NEWTAPE.
REPFILE,NEWTAPE,TPXXXK,DEFINE=YES.
$UNLOAD(NVETAPE,TPXXXK,NEWTAPE,LIST,NVEDIR,EMPTY)
$SKIP,NOERROR.
  $EXIT.
  $UNLOAD(NVETAPE,TPXXXK,NEWTAPE,LIST,NVEDIR,EMPTY)
  $IFE,(EF.EQ.TIE).OR.(EF.EQ.TAE),TERMINATED.
    $EXIT. INSDF *TERMINATED*
  $ENDIF,TERMINATED.
  $REVERT,ABORT. DEADSTART FILE NOT INSTALLED
$ENDIF,NOERROR.
$REVERT. DEADSTART FILE --> TPXXXK
.DATA,NVEDIR.
WRITEAR,10
LOADFILE,EMPTY,ASCII180,NAME170=NULL
LOADFILE,EMPTY,ASCII180,NAME170=PROLOGS
LOADFILE,EMPTY,TERMINATOR,NAME170=TERM
ENDTAPE
LOADEND
.DATA,EMPTY
EMPTYFILE
AN ALMOST EMPTY FILE
/EOR
