PROCEDURE install_network_config_file (
  host_network            : string = $required
  system_id_array         : array of string = $required
  physical_data_array     : array of string = $required
  number_physical_entries : integer = $required
  defined_array           : array of string = $required
  host_name               : string = $required
  forward_search_range    : string = $required
  success                 : (var) boolean = $required
  status)

  VAR
    configuration_file: file =$local.defn
    count: integer
    cr_requested: string
    ignore: status
    local_status: status
  VAREND

  detach_file configuration_file status=ignore

  generate_defhn host_network configuration_file.$eoi
  count = 0
  FOR i = 1 TO number_physical_entries DO
    IF defined_array(i) = 'YES' THEN
      generate_defnc physical_data_array(i) system_id_array(i) ..
              configuration_file.$eoi
      count = count + 1
    IFEND
  FOREND

  IF count = 0 THEN
    put_line ('0No network configuration commands have been created.','  ')
    accept_line cr_requested input p='Press NEXT: '
    EXIT_PROC WITH $status(TRUE)
  IFEND

  IF host_name <> ' ' THEN
    generate_define_tcpip_host host_name=host_name forward_search_range=forward_search_range ..
       configuration_file=configuration_file.$eoi
  IFEND

  execute_task sp=logical_configuration_utility
    install_network_configuration i=configuration_file status=local_status
  quit

  detach_file configuration_file status=ignore

  IF local_status.normal THEN
    put_line ('0Network configuration installed.' '  ')
    accept_line cr_requested input p='Press NEXT: '
    success = TRUE
  ELSE
    display_value local_status
    put_line ('0Network configuration NOT installed.' '  ')
    accept_line cr_requested input p='Press NEXT: '
    success = FALSE
  IFEND

PROCEND install_network_config_file
