.PROC,LISTEXT*I,
T "- Text record name (or ALL or *)"   = (ALL=*,*,*F),
L "- Library file name"                = (*N=#FILE,*F),
UN "- User Name containing library"    = (*N=,*F),
O "- Output file name"                 = (*N=OUTPUT,*F),
.
.HELP
 The LISTEXT procedure LISts TEXT records from a library file.
 Requires CATALOG binaries with GENCAT entry point.

 Parameter   Default   Description
   Name       Value

   t                   TEXT record name to list (or ALL or *)
  [l]                  library file containing the TEXT record
  [un]                 user name in which library resides
  [o]        OUTPUT    local file to which output is listed

.HELP,T
 The T parameter selects the TEXT record name to list.
.HELP,L
 The L parameter names the file containing a library of TEXT records.
 The default value is the file containing this procedure.
.HELP,UN
 The UN parameter specifies the User Name location of the file.
 The default value is the User Name in which this procedure executes.
.HELP,O
 The O parameter names a local file to which TEXT records are listed.
 The default value is OUTPUT.
.ENDHELP
GETTEXT,T,L,UN,G=YYYYGRP.
$NOTE,YYYYCAT,NR.+1  TEXT RECORDS LISTED FROM LIBRARY L - UN+ +
DISLIB,ALL,,YYYYGRP,UN,YYYYCAT,DO=BRIEF.
$PACK,YYYYCAT.
$COPYBR,YYYYCAT,YYYYTMP.
GENLSTF(YYYYGRP,YYYYTMP,,CS612,CS612)
DISLIB,ALL,,L,UN,YYYYTMP,DO=FULL.
$PACK,YYYYTMP,O.
$UNLOAD,YYYYTMP,YYYYCAT,YYYYGRP.
$SKIP,NOERROR.
  $EXIT.
  $UNLOAD,YYYYTMP,YYYYCAT,YYYYGRP.
  $IFE,(EF.EQ.TIE).OR.(EF.EQ.TAE),TERMINATED.
    $EXIT. LISTEXT *TERMINATED*
  $ENDIF,TERMINATED.
  $REVERT,ABORT. LIST OF L FAILED
$ENDIF,NOERROR.
.IFE,$T$.EQ.$*$,LISTALL.
  $REVERT. ALL L TEXT --> O
.ELSE,LISTALL.
  $REVERT. TEXT T FROM L --> O
.ENDIF,LISTALL.
/EOR
