PROC activate_network_clock, actnc (
  maximum_connections, mc : integer 1..1000 = 1000
  status                  : var of status = $optional
  )

    create_variable nav$status kind=status
    create_variable nav$ignore_status kind=status
    create_variable nav$parameter_list kind=string

actnc_block: ..
  BLOCK

    EXIT actnc_block WHEN NOT nav$status.normal

    nav$parameter_list = 'maximum_connections=' // $strrep($value(maximum_connections))

    delete_system_task name=network_clock status=nav$status
    IF NOT nav$status.normal AND ($condition(nav$status.condition) <> 'OSE$SYSTEM_TASK_NOT_DEFINED') THEN
      EXIT actnc_block
    IFEND

    define_system_task name=network_clock l=$system.osf$operator_library_46d m=nam$bound_clock_manager ..
          p=nav$parameter_list automatic_restart=false deactivate_task_option=terminate ..
          idle_task_option=terminate restart_after_idle=true lm=$null lmo=none tel=warning status=nav$status
    EXIT actnc_block WHEN NOT nav$status.normal

    activate_system_task network_clock status=nav$status

  BLOCKEND actnc_block

  IF nav$status.normal THEN
    display_value 'Network clock activated.' o=$response
  IFEND

  EXIT_PROC WITH nav$status WHEN NOT nav$status.normal

PROCEND activate_network_clock
