PROC activate_network_file_access, actnfa (
  file_type, ft           : list of key exception, boot, domain_name_server, dump, library, configuration, ..
                                 load_procedure, terminal_procedure, user_procedure, validation, all = all
  maximum_connections, mc : integer 1..1000 = 1000
  maximum_dumps, md       : integer 0..1000 = 10
  maximum_dump_size, mds  : integer = 16000000
  status                  : var of status = $optional
  )

  create_variable nav$status kind=status
  create_variable nav$ignore_status kind=status
  create_variable nav$parameter_list kind=string

actnfa_block: ..
  BLOCK

    EXIT actnfa_block WHEN NOT nav$status.normal

    nav$parameter_list = 'file_type=('

    FOR nav$set_count = 1 TO $set_count(file_type) DO
      nav$parameter_list = nav$parameter_list // ' ' // $strrep($value(file_type, nav$set_count, 1))
    FOREND

    nav$parameter_list = nav$parameter_list // ') '
    nav$parameter_list = nav$parameter_list // 'maximum_connections=' // $strrep(..
          $value(maximum_connections)) // ' '
    nav$parameter_list = nav$parameter_list // 'maximum_dumps=' // $strrep($value(maximum_dumps)) // ' '
    nav$parameter_list = nav$parameter_list // 'maximum_dump_size=' // $strrep($value(maximum_dump_size))

    delete_system_task name=network_file_access status=nav$status
    IF NOT nav$status.normal AND ($condition(nav$status.condition) <> 'OSE$SYSTEM_TASK_NOT_DEFINED') THEN
      EXIT actnfa_block
    IFEND

    define_system_task name=network_file_access l=$system.osf$operator_library_46d ..
          sp=nap$file_access_me ..
          m=nam$bound_file_access_manager p=nav$parameter_list automatic_restart=false ..
          deactivate_task_option=terminate idle_task_option=terminate restart_after_idle=true lm=$null ..
          lmo=none tel=warning status=nav$status
    EXIT actnfa_block WHEN NOT nav$status.normal

    activate_system_task network_file_access status=nav$status

  BLOCKEND actnfa_block

  IF nav$status.normal THEN
    display_value 'Network file access activated.' o=$response
  IFEND

  EXIT_PROC WITH nav$status WHEN NOT nav$status.normal

PROCEND activate_network_file_access
