PROCEDURE rap$combine_builtin_library (
  nosve_builtin_library, nbl: file = $required
  site_builtin_library, sbl: file = $required
  builtin_library, bl: file = $required
  status)


*IF $variable(wev$proc_doc,declared)<>'UNKNOWN'
"
"   This procedure combines a site-specified version of the file
"   BUILTIN_LIBRARY with the system released version of BUILTIN_LIBRARY.
"   and places the result in the file specified by the parameter
"   BUILTIN_LIBRARY.
"
*IFEND


  "$FORMAT=OFF
  VAR
    command_file: file = $local//$name($unique)
    ignore_status: status
    local_status: status
  VAREND
  "$FORMAT=ON"


  IF $file(site_builtin_library permanent) THEN
    $system.put_line (' Merging '//$string(site_builtin_library)//' ..' ..
       '    with '//$string(nosve_builtin_library)) o=$response

COLLECT_TEXT o=command_file until='**'
  $system.CREATE_OBJECT_LIBRARY
    add_modules l=nosve_builtin_library
    combine_modules l=site_builtin_library
    generate_library l=builtin_library
  QUIT
**
    $system.include_file command_file status=local_status
    $system.delete_file command_file status=ignore_status

  IFEND

  EXIT procedure WITH local_status WHEN NOT local_status.normal

PROCEND rap$combine_builtin_library
