PROCEDURE (HIDDEN) rap$create_aam_recovery_log (
  status)

*copy rav$system_paths

  "$FORMAT=OFF
  VAR
    command_file: file = $fname($unique)
    ignore_status: status
    local_status: status
    aam_recovery_log: file = rav$system.aam.shared_recovery_log
  VAREND
  "$FORMAT=ON"

  $system.create_catalog c=aam_recovery_log status=local_status

  IF local_status.normal THEN
    $system.create_catalog_permit c=aam_recovery_log group=public access_mode=(read write) ..
          share_mode=none
  IFEND

  IF (local_status.normal) OR ($condition(local_status.condition)= 'PFE$NAME_ALREADY_SUBCATALOG') THEN

COLLECT_TEXT command_file until='COLLECT_END'
  TASK ring=6
    PUSH command_list
    $system.create_command_list_entry e=$system.osf$command_library
    ADMINISTER_RECOVERY_LOG
      use_log c=aam_recovery_log
      configure_log_residence status=ignore_status
    QUIT
    POP command_list
  TASKEND
COLLECT_END

    $system.include_file command_file status=local_status
    $system.delete_file command_file status=ignore_status

  IFEND

  EXIT procedure WITH local_status WHEN NOT local_status.normal

PROCEND rap$create_aam_recovery_log
