PROCEDURE rap$define_tcp_time_server (
  status: (var) status )

    create_variable command_file k=string v='$local.'//$unique
    create_variable define_status_1 k=status
    create_variable define_status_2 k=status
    create_variable ignore_status k=status
    create_variable local_status k=status

  collect_text $fname(command_file) until='  collect_end'
    $system.osf$command_library.manage_network_applications
"     put_line 'WARNING - TCP/IP Gateway support terminated at release level 1.7.1'
"     display_client_status client=osa$tcp_time_server output=$null   status=define_status_1
"     IF define_status_1.normal THEN
"       activate_client client=osa$tcp_time_server status=define_status_1
"     ELSEIF $condition(define_status_1.condition)='NAE$UNKNOWN_APPLICATION' THEN
"       define_client client=osa$tcp_time_server protocol=cdna_session status=define_status_1
"         change_maximum_connections mc=40
"       end_define_client
"       activate_client client=osa$tcp_time_server status=define_status_1
"     IFEND

      display_tcpip_status application=osa$tcp_time_server output=$null  status=define_status_2
      IF define_status_2.normal THEN
        activate_tcpip_application application=osa$tcp_time_server status=define_status_2
      ELSEIF $condition(define_status_2.condition)='NAE$UNKNOWN_APPLICATION' THEN
        define_tcpip_application application=osa$tcp_time_server protocol=stream_socket status=define_status_2
        end_define_tcpip_application
        activate_tcpip_application application=osa$tcp_time_server status=define_status_2
      IFEND
    quit
  collect_end

  include_file $fname(command_file) status=local_status
  delete_file $fname(command_file) status=ignore_status

  IF local_status.normal THEN
    IF define_status_1.normal THEN
      put_line ' CLIENT (tcp) time server applications are defined' o=$response
    ELSE
      disv define_status_1
    IFEND

    IF define_status_2.normal THEN
      put_line ' TCP/IP (tcp) time server applications are defined' o=$response
    ELSE
      disv define_status_2
    IFEND
  IFEND

  EXIT_PROC WITH local_status

PROCEND rap$define_tcp_time_server
