PROCEDURE rap$define_unnamed_tcp_appl (
  status: (var) status )

    VAR
      application_name : name = UNNAMED_TCP_APPLICATION
      command_file : file = $unique($local)
      define_status : status
      ignore_status : status
      local_status : status
    VAREND

  collect_text command_file until='  collect_end'
    $system.osf$command_library.manage_network_applications

      display_tcpip_status application=application_name output=$null  status=define_status
      IF define_status.normal THEN
        activate_tcpip_application application=application_name status=define_status
      ELSEIF $condition(define_status.condition)='NAE$UNKNOWN_APPLICATION' THEN
        define_tcpip_application application=application_name protocol=stream_socket status=define_status
        end_define_tcpip_application
        activate_tcpip_application application=application_name status=define_status
      IFEND
    quit
  collect_end

  include_file command_file status=local_status
  delete_file command_file status=ignore_status

  IF local_status.normal THEN
    IF define_status.normal THEN
      put_line '  '//$STRING(application_name)//' has been defined.' o=$response
    ELSE
      disv define_status
    IFEND
  IFEND

  EXIT_PROC WITH local_status

PROCEND rap$define_unnamed_tcp_appl
