PROCEDURE rap$delete_tcp_time_server (
  terminate_active_connections , tac : boolean = false
  status                             : (var) status = $optional )

  create_variable command_file k=string v='$local.'//$unique
  create_variable delete_status_1 k=status
  create_variable delete_status_2 k=status
  create_variable ignore_status k=status
  create_variable local_status k=status


COLLECT_TEXT $fname(command_file) until='COLLECT_END'
  $system.osf$command_library.manage_network_applications

    deactivate_client client=osa$tcp_time_server tac=terminate_active_connections ..
          status=delete_status_1
    IF delete_status_1.normal OR ($condition(delete_status_1.condition) = 'NAE$APPLICATION_ALREADY_INACTIV') THEN
      delete_client client=osa$tcp_time_server status=delete_status_1
    IFEND

    IF delete_status_1.normal OR ($condition(delete_status_1.condition) = 'NAE$UNKNOWN_APPLICATION') THEN
      delete_status_1.normal = true
    IFEND

    deactivate_tcpip_application application=osa$tcp_time_server tas=terminate_active_connections ..
          status=delete_status_2
    IF delete_status_2.normal OR ($condition(delete_status_2.condition) = 'NAE$APPLICATION_ALREADY_INACTIV') THEN
      delete_tcpip_application application=osa$tcp_time_server status=delete_status_2
    IFEND

    IF delete_status_2.normal OR ($condition(delete_status_2.condition) = 'NAE$UNKNOWN_APPLICATION') THEN
      delete_status_2.normal = true
    IFEND

  quit
COLLECT_END

  include_file $fname(command_file) status=local_status
  delete_file $fname(command_file) status=ignore_status

  IF NOT delete_status_1.normal THEN
    disv delete_status_1
  IFEND

  IF NOT delete_status_2.normal THEN
    disv delete_status_2
  IFEND

  EXIT_PROC WITH local_status

PROCEND rap$delete_tcp_time_server
