PROCEDURE rap$delete_unnamed_udp_appl (
  terminate_active_sockets, tas : boolean = false
  status                            : (var) status = $optional )

    VAR
      application_name : name = UNNAMED_UDP_APPLICATION
      command_file : file = $unique($local)
      delete_status : status
      ignore_status : status
      local_status : status
    VAREND

COLLECT_TEXT command_file until='COLLECT_END'
  $system.osf$command_library.manage_network_applications

    deactivate_tcpip_application application=application_name tas=terminate_active_sockets ..
          status=delete_status
    IF delete_status.normal OR ($condition(delete_status.condition) = 'NAE$APPLICATION_ALREADY_INACTIV') THEN
      delete_tcpip_application application=application_name status=delete_status
    IFEND

    IF delete_status.normal OR ($condition(delete_status.condition) = 'NAE$UNKNOWN_APPLICATION') THEN
      delete_status.normal = true
    IFEND

  quit
COLLECT_END

  include_file command_file status=local_status
  delete_file command_file status=ignore_status

  IF NOT delete_status.normal THEN
    disv delete_status
  IFEND

  EXIT_PROC WITH local_status

PROCEND rap$delete_unnamed_udp_appl
