
  PROCEDURE [INLINE] rap$get_majority_file_class
    (    subproduct_index: rat$subproduct_count;
         icr: rat$installation_control_record;
     VAR majority_class_keyword : ost$name;
     VAR majority_file_class : rmt$mass_storage_class;
     VAR status: ost$status);

?? PUSH (LISTEXT := ON) ??

    VAR
      attributes_p: ^rat$subproduct_attributes;


    attributes_p := icr.subproduct_processing_records_p^ [subproduct_index].subproduct_info_pointers.
          attributes_p;

    IF icr.processing_header_p^.installation_defaults.ignore_storage_class THEN
      majority_class_keyword := 'PRODUCT';
    ELSEIF (attributes_p^.service_critical_file_size > attributes_p^.product_file_size) AND
          (attributes_p^.service_critical_file_size > attributes_p^.user_permanent_file_size) THEN
      majority_class_keyword := 'SERVICE_CRITICAL_PRODUCT';
    ELSEIF (attributes_p^.user_permanent_file_size > attributes_p^.product_file_size) AND
          (attributes_p^.user_permanent_file_size > attributes_p^.service_critical_file_size) THEN
      majority_class_keyword := 'USER_PERMANENT_FILE';
    ELSE
      majority_class_keyword := 'PRODUCT';
    IFEND;

    rmp$convert_keyword_to_class (majority_class_keyword, majority_file_class, status);

  PROCEND rap$get_majority_file_class;

{ PURPOSE:
{   This procedure returns the file storage class for the majority of the
{   subproducts files based on size.  The majority storage class is
{   returned as a keyword and a class character symbol.
{
{ DESIGN:
{   The installation default IGNORE_STORAGE_CLASS is used to determine
{   whether file class should be honored.  When set to true the majority
{   class is defaulted to PRODUCT.  This is used for INSS testing purposes.
{
{ NOTES:
{

*copyc ost$status
*copyc rat$installation_control_record
*copyc rmp$convert_keyword_to_class
?? POP ??

