PROCEDURE (hidden) rap$install_deferred_products (
  status)


*IF $variable(rav$proc_doc,declared)<>'UNKNOWN'

" PURPOSE:
"   This procedure installs all currently deferred products.
"
" NOTES:
"
*IFEND


*copy rav$margin

  "$FORMAT=OFF
  VAR
    command_file: file = $unique($local)
    ignore_status: status
    local_status: status
    rav$system: (XREF) file
  VAREND
  "$FORMAT=ON"


  rap$display_message mm=initiation_messages mn=installing_deferred_products m=rav$margin t=$response ..
        status=ignore_status

COLLECT_TEXT o=command_file
  install_software
    IF rav$system <> :$system.$system THEN
      change_installation_defaults system_catalog=rav$system
    IFEND
    activate_products s=all
  quit
**
  $system.include_file f=command_file status=local_status
  $system.delete_file f=command_file status=ignore_status

  rap$create_operator_environment

  IF NOT local_status.normal THEN
    rap$press_next
  IFEND

  IF local_status.normal THEN
    rap$display_message mm=initiation_messages mn=deferred_products_installed m=rav$margin t=$response ..
          status=ignore_status
  IFEND

  EXIT procedure WITH local_status WHEN NOT local_status.normal

PROCEND rap$install_deferred_products

