PROCEDURE install_version_independent, insvi (
  cdcnet_catalog, cc: file = $required
  version_catalog, vc: file = $required
  status)

  "Install files to $SYSTEM.CDCNET.VERSION_INDEPENDENT catalog."

  "$FORMAT=OFF
  VAR
    local_status: status
    ignore_status: status
    name_version_independent: name = version_independent

    rav$subproduct_information: (XREF) rat$subproduct_information
    rav$installation_defaults: (XREF) rat$installation_defaults
    rav$installation_environment: (XREF) rat$installation_environment

    version_independent_names: array 1..5 of name = (..
      npailib ..
      npahlib ..
      cdcnet_version ..
      di_message_templates ..
      command_library ..
      )

  VAREND
  "$FORMAT=ON"

  install_block: ..
    BLOCK

  $system.put_line l=' Installing CDCNET Version Independent files ...' o=$job_log

" create the catalog"

  $system.create_catalog c=cdcnet_catalog//name_version_independent status=local_status
  IF local_status.normal THEN
    $system.create_catalog_permit cdcnet_catalog//name_version_independent ..
      g=public am=(read, execute) sm=(read, execute)
  ELSE
   local_status.normal = TRUE
  IFEND

" Install the files

  FOR loop = 1 to $upper_bound(version_independent_names) DO
    IF (rav$subproduct_information.subproduct_name <> CDCNET_OPEN_SHOP) OR ..
       ((rav$subproduct_information.subproduct_name  = CDCNET_OPEN_SHOP) and ..
         ($file(version_catalog//name_version_independent//version_independent_names(loop), permanent))) THEN
      install_file ..
        f=version_catalog//name_version_independent//version_independent_names(loop) ..
        t=cdcnet_catalog//name_version_independent//version_independent_names(loop) ..
        spc=true ra=(11 11 11) status=local_status
      EXIT install_block WHEN NOT local_status.normal
    IFEND
  FOREND


  BLOCKEND install_block

  EXIT procedure WITH local_status WHEN NOT local_status.normal

PROCEND install_version_independent
