PROCEDURE (HIDDEN) rap$verify_configuration (
  status: (var) status = $optional
  )

*IF $variable(rav$proc_doc,declared)<>'UNKNOWN'

" PURPOSE:
"   This procedure verifies that the network configuration file is present and valid.
*IFEND


  "$FORMAT=OFF
  VAR
    ignore_status: status
    local_status: status
    rav$event_message: (XREF) status
    rav$system: (XREF) file
    network_configuration_file: file = rav$system.network.configuration
    verify_configuration: file = $fname($unique)
  VAREND
  "$FORMAT=ON"


  rav$event_message=$status(false, 'RA', rae$verifying_error, 'the network configuration')

  $system.include_line 'permanent = $file(network_configuration_file, permanent)' status=local_status

  IF local_status.normal AND permanent THEN

COLLECT_TEXT o=verify_configuration until='END_COLLECT'

    execute_task sp=logical_configuration_utility
      verify_network_configuration i=network_configuration_file e=$response
    quit

END_COLLECT

    $system.include_file f=verify_configuration status=local_status
    $system.delete_file f=verify_configuration status=ignore_status

  ELSE
    local_status=$status(false, 'RA', rae$missing_configuration, 'network')
  IFEND

  IF local_status.normal THEN
    rav$event_message.normal=true
  ELSE
    EXIT procedure WITH local_status
  IFEND

PROCEND rap$verify_configuration
