// JOB VSB022,,B000,B000
// GBL   PCH=NO
// GBL   PUNCH=NO
// GBL   T=NO
// GBL   TAPE=NO
// GBL   C=80
// GBL   LU=30
// DVC 20  // LFD PRNTR
// OPR ****--BEGIN--TO---COMPILE--VSCOB1--*****
// WORK1    DVC=50,VOL=SDIVSB
// WORK2 DVC=50,VOL=SDIVSB
// WORK3 DVC=50,VOL=SDIVSB
// OPTION      SYSDUMP
// OPTION      SUB
// EXEC COBOLB
// PARAM LST=(A,E,K,L,S,C)
// PARAM OUT=(P,E,S)
/$
       IDENTIFICATION DIVISION.                                         VSBSEQ01
       PROGRAM-ID.             VSCOB1.                                  VSBSEQ01
       AUTHOR.                 JAN M. WIEWIORA.                         VSBSEQ01
       INSTALLATION.           S D I.                                   VSBSEQ01
       DATE-WRITTEN.           AUGUST 14, 1974.                         VSBSEQ01
       DATE-COMPILED.          AUGUST 1974.                             VSBSEQ01
       SECURITY.               V S B  GROUP.                            VSBSEQ01
       REMARKS.                THIS PROGRAM IS TO USE THE DIFFERENT     VSBSEQ01
                               SEQUENTIAL ACCESS MODES AVAILABLE TO     VSBSEQ01
                               COBOL.                                   VSBSEQ01
       ENVIRONMENT DIVISION.                                            VSBSEQ01
       CONFIGURATION SECTION.                                           VSBSEQ01
       SOURCE-COMPUTER.        UNIVAC-9030.
       OBJECT-COMPUTER.        UNIVAC-9030.
       SPECIAL-NAMES.                                                   VSBSEQ01
                               SYSDATE IS UDATE,                        VSBSEQ01
                               SYSTIME IS UTIME,                        VSBSEQ01
                               SYSCHAN-15 IS TOP,                       VSBSEQ01
                               SYSCONSOLE IS OPR.                       VSBSEQ01
       INPUT-OUTPUT SECTION.                                            VSBSEQ01
       FILE-CONTROL.                                                    VSBSEQ01
                   SELECT  DISK ASSIGN TO DISC-8414.                    VSBSEQ01
                   SELECT TAAPE ASSIGN TO TAPE.                         VSBSEQ01
                   SELECT PRNTR ASSIGN TO PRINTER.                      VSBSEQ01
                   SELECT CARDI ASSIGN TO CARD-READER.                  VSBSEQ01
                   SELECT CARDO ASSIGN TO CARD-PUNCH.                   VSBSEQ01
       DATA DIVISION.                                                   VSBSEQ01
       FILE SECTION.                                                    VSBSEQ01
       FD  DISK                                                         VSBSEQ01
           BLOCK CONTAINS 2 RECORDS
           RECORD CONTAINS 96 CHARACTERS
           LABEL RECORDS ARE STANDARD                                   VSBSEQ01
           RECORDING MODE IS F                                          VSBSEQ01
           VALUE OF ID IS 'COBOL-SQ'.                                   VSBSEQ01
       01  DISK-REC            PIC X(96).
       FD  TAAPE                                                        VSBSEQ01
           BLOCK CONTAINS 2 RECORDS
           RECORD CONTAINS 96 CHARACTERS
           LABEL RECORDS ARE STANDARD                                   VSBSEQ01
           RECORDING MODE IS F.                                         VSBSEQ01
       01  TAPE-REC            PIC X(96).
       FD  PRNTR LABEL RECORDS ARE OMITTED.                             VSBSEQ01
       01  PLINE               PIC X(120).                              VSBSEQ01
       FD  CARDI LABEL RECORDS ARE OMITTED.                             VSBSEQ01
       01  FILLER              PIC X(&C).
       FD  CARDO LABEL RECORDS ARE OMITTED.                             VSBSEQ01
       01  CO-REC              PIC X(80).                               VSBSEQ01
       WORKING-STORAGE SECTION.                                         VSBSEQ01
       01  S                   PIC X      VALUE SPACE.                  VSBSEQ01
       01  HLINE.                                                       VSBSEQ01
           03  FILLER          PIC X(6) VALUE 'TIME: '.                 VSBSEQ01
           03 HTIME.
           05  HH              PIC XX.                                  VSBSEQ01
           05  FILLER          PIC X    VALUE ':'.                      VSBSEQ01
           05 SS               PIC XX.
           03 FILLER PIC X(31) VALUE '  VSCOB1 SEQUENTIAL FILE LIST  '. VSBSEQ01
           03  FILLER          PIC X(6) VALUE 'DATE: '.                 VSBSEQ01
           03 HDATE.
           05 MM               PIC XX.                                  VSBSEQ01
           05 FILLER           PIC X    VALUE '/'.                      VSBSEQ01
           05 DD               PIC XX.                                  VSBSEQ01
           05 FILLER           PIC X    VALUE '/'.                      VSBSEQ01
           05 YY               PIC XX.                                  VSBSEQ01
       01  ATIME.
           05 HH               PIC XX.
           05 SS               PIC XX.
       01  ADATE.                                                       VSBSEQ01
           05 YY               PIC XX.                                  VSBSEQ01
           05 MM               PIC XX.                                  VSBSEQ01
           05 DD               PIC XX.                                  VSBSEQ01
       01  CI-REC              PIC X(96).
       01  ANS                 PIC X  VALUE ' '.                        VSBSEQ01
           88 YES              VALUE 'Y'.                               VSBSEQ01
       01  SLU                 PIC X  VALUE '0'.                        VSBSEQ01
       01  SLT                 PIC X  VALUE '0'.                        VSBSEQ01
       PROCEDURE DIVISION.                                              VSBSEQ01
       CONSOLE-ACCEPT-ROUTINE.                                          VSBSEQ01
           ACCEPT ADATE FROM UDATE.
           ACCEPT ATIME FROM UTIME.
           MOVE YY OF ADATE TO YY OF HDATE
           MOVE MM OF ADATE TO MM OF HDATE
           MOVE DD OF ADATE TO DD OF HDATE
           MOVE HH OF ATIME TO HH OF HTIME
           MOVE SS OF ATIME TO SS OF HTIME
           DISPLAY 'DO YOU NEED THE PUNCH'.                             VSBSEQ01
           ACCEPT ANS FROM OPR.                                         VSBSEQ01
           IF YES OPEN OUTPUT CARDO MOVE '1' TO SLU MOVE ' ' TO ANS.    VSBSEQ01
           DISPLAY 'DO YOU NEED THE TAPE'.                              VSBSEQ01
           ACCEPT ANS FROM OPR.                                         VSBSEQ01
           IF YES OPEN OUTPUT TAAPE MOVE '1' TO SLT MOVE ' ' TO ANS.
           OPEN INPUT CARDI, OUTPUT DISK, PRNTR.
           WRITE PLINE FROM S BEFORE TOP.
           WRITE PLINE FROM HLINE BEFORE 2.
       INPUT-ROUTINE.                                                   VSBSEQ01
           READ CARDI INTO CI-REC AT END GO TO E-O-S.
           IF SLU = '1' WRITE CO-REC FROM CI-REC.                       VSBSEQ01
           IF SLT = '1' WRITE TAPE-REC FROM CI-REC.                     VSBSEQ01
           WRITE DISK-REC FROM CI-REC INVALID KEY DISPLAY
                 'OUTPUT DISC FULL ' GO TO E-O-S.
           WRITE PLINE FROM CI-REC.
           GO TO INPUT-ROUTINE.                                         VSBSEQ01
       E-O-S.                                                           VSBSEQ01
           CLOSE CARDI, DISK.
           IF SLU = '1' CLOSE CARDO.                                    VSBSEQ01
           IF SLT = '1' CLOSE TAAPE.                                    VSBSEQ01
           WRITE PLINE FROM S BEFORE TOP.
                   CLOSE PRNTR.                                         VSBSEQ01
           DISPLAY 'END OF VSB022' UPON OPR.
           STOP RUN.                                                    VSBSEQ01
/*
// OPR ****--BEGIN--LINK--AND--LOAD--VSCOB1--****
// DVC 20 // LFD PRNTR
// DVC 50 // VOL SDIVSB // LBL VSBLIB // LFD LOAD
// WORK1    DVC=50,VOL=SDIVSB
// EXEC LNKEDT
// PARAM OUT=LOAD
/$
 LOADM VSCOB1
/*
// IF    ('&T' EQ 'NO')CKPU
//TAPE   JSET  &T
//CKPU   NOP
// IF    ('&PCH' EQ 'NO')CKCD
//PUNCH  JSET &PCH
//CKCD   NOP
// IF    ('&C' EQ '80')START
//LU     JSET 34
//START  NOP
// OPR ****--BEGIN--EXECUTE--OF--VSCOB1--****
// IF ('&TAPE' EQ 'NO')NOTAPE
// DVC 90      // VOL SP0002(NOV)  // LFD TAAPE
//NOTAPE NOP
// IF ('&PUNCH' EQ 'NO')NOPCH
// DVC 40 // LFD CARDO
//NOPCH NOP
// DVC   &LU   // LFD CARDI
// DVC 20 // LFD PRNTR
// DVC 50 // VOL SDIVSB // LBL COBOLSAM  // LFD DISK,,INIT
// DVC 50 // VOL SDIVSB // LBL VSBLIB // LFD LOAD
// EXEC VSCOB1,LOAD
/&
