         MACRO                                                          EMV00010
&TAG     EMVFB &LFD,&VFB,&ERR                                           EMV00020
         LCLA  &PARAM                                                   EMV00030
&PARAM   SETA  0                                                        EMV00040
&TAG     DS    0H                                                       EMV00050
         AIF   (('&LFD'(1,3) EQ '(1)') OR ('&LFD' EQ '1')).DOVFB        EMV00060
         AIF   ('&LFD' EQ '').LFDERR                                    EMV00070
&PARAM   SETA  1                                                        EMV00080
         AGO   .DOVFB                                                   EMV00090
.LFDERR  ANOP                                                           EMV00100
         MNOTE 'MISSING LFD ADDRESS-ASSUMED R1 IS LOADED'               EMV00110
.DOVFB   ANOP                                                           EMV00120
         AIF   (('&VFB'(1,3) EQ '(0)') OR ('&VFB' EQ '0')).GENSVC       EMV00130
         AIF   ('&VFB' EQ '').VFBERR                                    EMV00140
&PARAM   SETA  &PARAM+2                                                 EMV00150
         AGO   .GENSVC                                                  EMV00160
.VFBERR  ANOP                                                           EMV00170
         MNOTE 'MISSING VFB ADDRESS-ASSUMED R0 IS LOADED'               EMV00180
.GENSVC  ANOP                                                           EMV00190
         AIF   (&PARAM = 0).GENSVC1                                     EMV00200
         CNOP  0,4                                                      EMV00210
         AIF   (&PARAM = 3).GENBOTH                                     EMV00220
         AIF   (&PARAM = 2).GENVFB                                      EMV00230
         L     1,*+8                                                    EMV00240
         B     *+8                                                      EMV00250
         DC    A(&LFD)                                                  EMV00260
         AGO   .GENSVC1                                                 EMV00270
.GENVFB  ANOP                                                           EMV00280
         L     0,*+8                                                    EMV00290
         B     *+8                                                      EMV00300
         DC    A(&VFB)                                                  EMV00310
         AGO   .GENSVC1                                                 EMV00320
.GENBOTH ANOP                                                           EMV00330
         L     1,*+12                                                   EMV00340
         L     0,*+12                                                   EMV00350
         B     *+12                                                     EMV00360
         DC    A(&LFD)                                                  EMV00370
         DC    A(&VFB)                                                  EMV00380
.GENSVC1 ANOP                                                           EMV00390
         SVC   76                       ISSUE LOAD VFB                  EMV00400
         LTR   0,0                      ERROR                           EMV00410
         AIF   ('&ERR' EQ '').GENCANC                                   EMV00420
         AIF   ('&ERR'(1,1) EQ '(').TESTREG                             EMV00430
         BM    &ERR                     (NO,YES-BRANCH)                 EMV00440
         MEXIT                                                          EMV00450
.GENCANC ANOP                                                           EMV00460
         BNM   *+6                      (YES,NO-BRANCH)                 EMV00470
         SVC   28                       ERROR-CANCEL                    EMV00480
         MEXIT                                                          EMV00490
.TESTREG ANOP                                                           EMV00500
         AIF   (('&ERR'(1,3) EQ '(0)') OR ('&ERR' EQ '0') OR ('&ERR'(1,XEMV00510
               3) EQ '(1)') OR ('&ERR' EQ '1')).ERRERR                  EMV00520
         BMR   &ERR                     (NO,YES-BRANCH)                 EMV00530
         MEXIT                                                          EMV00540
.ERRERR  ANOP                                                           EMV00550
         MNOTE 'ERROR ADDRESS REGISTER INCORRECT-LOCATION 0 FOR PATCH'  EMV00560
         BM    0                                                        EMV00570
         MEND                                                           EMV00580
